solved 隐藏EFI盘符 Hidden EFI volume

Code:
@echo off

setlocal enabledelayedexpansion

if exist %temp%\ventoy_vol.txt (

    del %temp%\ventoy_vol.txt

)

if exist %temp%\ventoy_diskpart_cmd.txt (

    del %temp%\ventoy_diskpart_cmd.txt

)

echo list volume >%temp%\ventoy_diskpart_cmd.txt

diskpart /s %temp%\ventoy_diskpart_cmd.txt |findstr /i VTOYEFI >%temp%\ventoy_vol.txt

echo Find Volume：

type %temp%\ventoy_vol.txt

for /f "tokens=1,2,3" %%a in (%temp%/ventoy_vol.txt) do (

    set "volumeNumber=%%b"

    set "volumeLetter=%%c"

    echo volumeNumber： !volumeNumber!

    echo volumeLetter： !volumeLetter!

)

if "!volumeNumber!" EQU "" (

    echo 未找到目标卷标编号，即将退出 volumeNumber not found

    ping -n 5 127.0.0.1>nul

    exit

)

if "!volumeLetter!" EQU "" (

    echo 未找到目标驱动器号，即将退出 volumeLetter not found

    ping -n 5 127.0.0.1 >nul

    exit

)

rem echo select volume !volumeNumber!

rem echo remove letter=!volumeLetter!

echo select volume !volumeNumber! >%temp%\ventoy_diskpart_cmd.txt

echo remove letter=!volumeLetter! >>%temp%\ventoy_diskpart_cmd.txt

diskpart /s %temp%\ventoy_diskpart_cmd.txt

echo 隐藏完毕 Done.

del %temp%\ventoy_diskpart_cmd.txt

del %temp%\ventoy_vol.txt